Descriptions et exemples pour le raytracer POV-Ray par Friedrich A. Lohmüller
Plantes avec POV-Ray      
English English English
Italiano Italiano
Deutsch Deutsch

Page d'accueil
- Tutoriel POV-Ray

- Plantes avec POV-Ray
   - Arbres avec POV-Tree
     - POV-Tree exemples
     - Textures pour POV-Tree
   - Arbres avec Arbaro
     - Arbaro exemples
    > Textures pour Arbaro

   - D'autres exemples de plantes

  - Objets de Plantes prêt à l'usage
  - Insert Menu Add-on
                                   
 Textures pour les arbres de Arbaro      
Utilise JavaScript pour afficher des images en hautes résolutions.

Dans les fichiers de données Arbaro des mailles de l'arbre (par ex. ici: sassafras_m.inc)
toutes les mailles sont déclarées sans textures !
Ajout de textures :
// tree textures:  --------------------------------
#declare Stem_Texture =
texture{ pigment{ color rgb< 0.75, 0.5, 0.30>*0.25}
        normal{bumps 0.75 scale<0.025,0.075,0.025>}
         finish { phong 0.2 }
       } // end of texture
#declare Leaves_Texture_1 =
texture{ pigment{ color rgbf<0.2,0.5,0, 0.1>*0.75}
         normal { bumps 0.15 scale 0.05 }
         finish { phong 1 }
       } // end of texture
#declare Leaves_Texture_2 =
texture{ pigment{ color rgbf<0.2,0.5,0, 0.2>*0.25}
         normal { bumps 0.15 scale 0.05 }
         finish { phong 0.2 }
       } // end of texture
//-------------------------------------------------
#include "sassafras_m.inc"
//-------------------------------------------------
// tree with leaves
union{ object{ sassafras_13_stems
               texture{ Stem_Texture }
             } //---------------------
       object{ sassafras_13_leaves
               double_illuminate
               texture{ Leaves_Texture_1 }
               interior_texture{ Leaves_Texture_2 }
             } //---------------------
       rotate <0,90,0>
       tanslate <0,0,0>
     } // end of union

// tree without leaves
object{ sassafras_13_stems
        texture{ Stem_Texture }
        scale 0.7
        rotate <0,45,0>
        translate <11,0,0>
      } //------------------------  

Exemple de l'arbre « sassafras » avec textures.
Description de scène pour POV-Ray :
"sassafras_m000.pov" et "sassafras_m.inc" (25.4 MB)
Ajout réel ciel et terre :
Exemple de l'arbre « sassafras » avec textures dans une monde réel.
Description de scène pour POV-Ray :
"ATree_sassafras_m100.pov" et "sassafras_m.inc" (25.4 MB)
// automn leaves:
#declare Leaves_Texture_1 =
texture{ pigment{ bozo
                  color_map{
                  [0.0 color rgbf<1,0.1,0,0.2>*0.7]
                  [1.0 color rgbf<1,0.7,0, 0.2>]
                           } // color_map
                }  // pigment
         normal { bumps 0.15 scale 0.05 }
         finish { phong 1 reflection 0.00}
       } // end of texture
//-------------------------------------------------
#declare Leaves_Texture_2 =
texture{ pigment{ color rgbf<1,0.5,0.0,0.4>*0.5}
         normal { bumps 0.15 scale 0.05 }
         finish { phong 0.2 }
       } // end of texture
//-------------------------------------------------
Exemple de l'arbre « sassafras » avec textures d'automne.
Description de scène pour POV-Ray :
"ATree_sassafras_m400.pov" et "sassafras_m.inc" (25.4 MB)
top

© Friedrich A. Lohmüller, 2015
homepage:http://www.f-lohmueller.de